سيتم إلصاق مستشعر الاهتزاز (أو الطقطقة) على الباب ليكون مباشرا لأي طرقة على الباب. إذا استمع لعدد محدد من الطقطقات يفصل بينهما وقت محدد، سيقوم بتنشيط المحرك الكهربائي. هذا اﻷخير سيدير مفتاح الباب المثبت عليه وبالتالي ينفتح لك الباب. إذ لم تكن الطرقات كما هي، سيتهيأ الجهاز لاستماع الطرقة من جديد.

/*  شيفرة الطرقة السرية   

   Steve Hoefer  من طرف

   http://grathio.com الموقع 

   0.1.10.20.10 الإصدار

   Licensed under Creative Commons Attribution-Noncommercial-Share Alike 3.0

   http://creativecommons.org/licenses/by-nc-sa/3.0/us/

   (باختصار: افعل بالشيفرة ما تريد، فقط قم بإضافة هذا السطر وما فوقه من سطور، لا تبعه أو تستعمله في أي شيء دون الاتصال بي )      

   Analog Pin 0: Piezo المستشعر

   Digital Pin 2: الزر الكهربائي

   Digital Pin 3: المحرك الكهربائي

   Digital Pin 4: الصمام الأحمر

   Digital Pin 5: الصمام الأخضر

 */

//................................................................................................................

// تعريف المرابط

const int knockSensor = 0;           // مربط مستشعر الاهتزاز

const int programSwitch = 2;

const int lockMotor = 3;                 // مربط المحرك الكهربائي

const int redLED = 4;                     // مربط الصمام الاحمر

const int greenLED = 5;                // مربط الصمام الأخضر

// تعريف الثوابت

//من أجل التحكم بخصائص الجهاز

const int threshold = 3;              // أصغر إشارة من المستشعر لحفظ الطرقة

const int rejectValue = 25;        // إذا مر هذا الوقت على طقطقة واحدة فلن يتم فتح الباب

const int averageRejectValue = 15; //متوسط الوقت للطقطقات. إذا تم تجاوزه لن ينفتح الباب

 /*يستعد الجهاز لاستقبال طرقة أخرى بعد مرور 150 جزء من الثانية على الطرقة السابقة*/

const int knockFadeTime = 150;   

const int lockTurnTime = 650;      // عدد أجزاء الثانية المتطلبة لجعل المحرك يقوم بنصف دورة

const int maximumKnocks = 20;       // العدد الأقصى للطقطقات المسموح بها

// بعد انتهاء هذه المدة الزمنية نستنج أن عدد الطقطقات قد استكمل

const int knockComplete = 1200;    

// تعريف المتغيرات

// الطرقة الافتراضية

int secretCode[maximumKnocks] = {50, 25, 25, 50, 100, 50, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0}; 

 //تسجل الطرقة الجديدة في هذا الجدول مع الزمن الذي يفصل بين طقطقاتها

int knockReadings[maximumKnocks]; 

int knockSensorValue = 0;           // القيمة المقروءة من المستشعر

 /* إذا تم الضغط على الرز نضع "صح" في هذا المتغير وإلا فستكون القيمة هي "خطأ"ه*/

int programButtonPressed = false; 

//................................................................................................................

void setup()

{

  pinMode(lockMotor, OUTPUT);

  pinMode(redLED, OUTPUT);

  pinMode(greenLED, OUTPUT);

  pinMode(programSwitch, INPUT);

  Serial.begin(9600);                           // سرعة التحويل لتهيئة البطاقة البرمجية

  Serial.println("Program start."); 

  digitalWrite(greenLED, HIGH);        // نقوم باشعال الصمام اﻷخضر للإشارة إلى أن الجهاز قد بدأ بالعمل

}

//................................................................................................................

void loop()

{

  knockSensorValue = analogRead(knockSensor);  // التنصت لأي طقطقة على الباب

  if (digitalRead(programSwitch)==HIGH) // هل تم الضغط على الزر الكهربائي؟

  {

    programButtonPressed = true;          // نعم، وبالتالي نضع "صح" في المتغير

    digitalWrite(redLED, HIGH);              // نشعل ضوء الصمام الاحمر

  }

  else

 {

    programButtonPressed = false;

    digitalWrite(redLED, LOW);

  }

  if (knockSensorValue >=threshold)  listenToSecretKnock();

}

//................................................................................................................

//تسجل هذه الدالة زمن الطقطقات على الباب

void listenToSecretKnock()

{

  Serial.println("knock starting");  // جملة للإعلان عن عملية تسجيل الطرقة السرية

  int i = 0;

  // تهيئة جدول الطقطقات

  for (i=0; i < maximumKnocks; i++)  knockReadings[i] = 0; 

  int currentKnockNumber = 0;                     // مؤشر لخانات الجدول

  int startTime = millis();                                 // تسجيل زمن البداية

  int now = millis();

  digitalWrite(greenLED, LOW);                  //نشعل ضوء الصمام الاخضر كإشارة للطرقة

  if (programButtonPressed==true)            // والضوء الاحمر كإشارة لتسجيل طرقة جديدة

                 digitalWrite(redLED, LOW);             

  delay(knockFadeTime);                             // ننتظر لبعض الوقت حتى نستعد لتسجيل التالية

  digitalWrite(greenLED, HIGH); 

  if (programButtonPressed==true)     digitalWrite(redLED, HIGH);                       

 do

 {

    //ننصت للطقطقة التالية أو يتم الانتظار حتى ينفذ الوقت المسموح به

    knockSensorValue = analogRead(knockSensor);

    if (knockSensorValue >=threshold)                   //لنسجل الطقطقة

    {

      //نسجل الزمن الفاصل بينها وبين سابقتها

      Serial.println("knock.");

      now=millis();

      knockReadings[currentKnockNumber] = now - startTime;

      currentKnockNumber++;                             //تزداد قيمة المؤشر استعدادا للطقطقة التالية

      startTime=now;                                              // إعادة تهيئة زمن البداية من أجل الطقطقة التالية

      digitalWrite(greenLED, LOW); 

      // والضوء الأحمر أيضا إذا كنا ما نزال نريد تسجيل طقطقة أخرى

      if (programButtonPressed==true)  digitalWrite(redLED, LOW);       

      delay(knockFadeTime);                              // مرة أخرى ننتظر لبعض الوقت استعدادا للتالي

      digitalWrite(greenLED, HIGH);

      if (programButtonPressed==true)   digitalWrite(redLED, HIGH);                        

    }

    now=millis();   

    //هل تجاوزنا الوقت المسموح به للانتظار أم تجاوزنا عدد الطقطقات المسموح به

   } while ((now-startTime < knockComplete) && (currentKnockNumber < maximumKnocks));

  // تم تسجيل الطرقة، لنرى ما الذي يمكن العمل بها

  if (programButtonPressed==false)            //التاكد من موافقة الطرقة مع الطرقة السرية

  {

    if (validateKnock() == true) triggerDoorUnlock();

    else

    {

      Serial.println("Secret knock failed.");

      digitalWrite(greenLED, LOW);         

      // لم نفتح وبالتالي نظهر وميضا أحمر كإشارة لذلك

      for (i=0;i<4;i++) {  digitalWrite(redLED, HIGH);   delay(100);

                                  digitalWrite(redLED, LOW);   delay(100);  }

      digitalWrite(greenLED, HIGH);

    }

   }

  else  // تسجيل طرقة سرية جديدة

  {

    validateKnock();

    Serial.println("New lock stored.");

    /* نظهر وميضا متناوبت بين الأخضر والأحمر كإشارة على أنه تم تسجيل طرقة سرية جديدة بنجاح*/

    digitalWrite(redLED, LOW);

    digitalWrite(greenLED, HIGH);

    for (i=0;i<3;i++)

    {

      delay(100);  digitalWrite(redLED, HIGH);  digitalWrite(greenLED, LOW); 

      delay(100);  digitalWrite(redLED, LOW);  digitalWrite(greenLED, HIGH);     

    }

  }

} 

//................................................................................................................

// التحكم بالمحرك الكهربائي من أجل فتح الباب

void triggerDoorUnlock()

{

  Serial.println("Door unlocked!");

  int i=0; 

  // تدوير المحرك قليلا

  digitalWrite(lockMotor, HIGH);

  digitalWrite(greenLED, HIGH);

  delay (lockTurnTime);                         // ننتظر لبعض الوقت

  digitalWrite(lockMotor, LOW);            // ثم نوقف المحرك

  // وميض أخضر كإشارة لهذه العملية

  for (i=0; i < 5; i++)  { digitalWrite(greenLED, LOW);  delay(100);

                                  digitalWrite(greenLED, HIGH); delay(100);  }  

}

//................................................................................................................

// للتأكد من موافقة الطرقة المسجلة بالطرقة السرية

boolean validateKnock()

{

  int i=0; 

  // أولا وقبل كل شيء، هل عدد الطقطقات صحيح؟

  int currentKnockCount = 0;

  int secretKnockCount = 0;

  int maxKnockInterval = 0;              

  for (i=0;i<maximumKnocks;i++)

 {

    if (knockReadings[i] > 0) currentKnockCount++;

    if (secretCode[i] > 0){                     //todo: precalculate this.

      secretKnockCount++;

    } 

    // للحصول على أقصى قيمة

    if (knockReadings[i] > maxKnockInterval) { maxKnockInterval = knockReadings[i]; }

  }

  // هل نريد أن نسجل طرقة جديدة فقط؟

  if (programButtonPressed==true)

  {

      for (i=0;i<maximumKnocks;i++)

        secretCode[i]= map(knockReadings[i],0, maxKnockInterval, 0, 100);

      // إظهار وميض للإشارة على أننا في مرحلة تسجيل طرقة جديدة

      digitalWrite(greenLED, LOW);  digitalWrite(redLED, LOW);   delay(1000); 

      digitalWrite(greenLED, HIGH);  digitalWrite(redLED, HIGH);   delay(50);

      for (i = 0; i < maximumKnocks ; i++)

      {

        digitalWrite(greenLED, LOW);   digitalWrite(redLED, LOW); 

        if (secretCode[i] > 0) // في حالة إذا كان هناك تأخر

        {

          delay( map(secretCode[i],0, 100, 0, maxKnockInterval));

          digitalWrite(greenLED, HIGH);   digitalWrite(redLED, HIGH);

        }

        delay(50);

      }

      return false;     // لن نفتح الباب عندما نريد تسجيل طرقة سرية جديدة

  }

  if (currentKnockCount  != secretKnockCount)  return false;

  /*  نقارن الآن بين الطرقة الجديدة. تجدر الاشارة إلى أنه لو كانت الطرقة بطيئة أو سريعة سينفتح الباب.

هذا سيجعل الباب أقل أمنا لكن لو غيرت الوقت أيضا فسيصبح استعماله صعبا شيئا ما إذ لم يكن المستعمل يتقن طرقته السرية بنجاح  */

  int totaltimeDifferences = 0;

  int timeDiff = 0;

  for ( i = 0; i < maximumKnocks; i++ )

  {

    knockReadings[i] = map(knockReadings[i], 0, maxKnockInterval, 0, 100);     

    timeDiff = abs(knockReadings[i] - secretCode[i]);

    if (timeDiff > rejectValue)  return false;

    totaltimeDifferences += timeDiff;

  }

  if (totaltimeDifferences / secretKnockCount > averageRejectValue) return false; 

  return true; 

}

for (i=0;i<maximumKnocks;i++)

{

   if (knockReadings[i] > 0) currentKnockCount++;

   if (secretCode[i] > 0){                     //todo: precalculate this.

      secretKnockCount++;

    }

 for ( i = 0; I < maximumKnocks; i++ )

  {

    knockReadings[i] = map(knockReadings[i], 0, maxKnockInterval, 0, 100);     

    timeDiff = abs(knockReadings[i] - secretCode[i]);

    if (timeDiff > rejectValue)  return false; 

    totaltimeDifferences += timeDiff;

  }